/scid Command - mIRC

mIRC

The /scid command can change the connection associated with the current script. When a command is not specified, mIRC changes the connection of the current script to the connection associated with the given Connecion ID. The rest of the code will continue to execute on that connection. When a command is specified, mIRC will execute the command on the connection specified by the Connection ID or the connections based on the switches provided. Any active connection changes are restored upon returning to the calling routine. A command can be executed on all or some of the connections depending on their types using the -a or -at<Type> switches.

Connection Type[edit]

1 = Connected
2 = Disconnected or Connecting
3 = 1+2 = Connected, Disconnected, or Connecting (Same as -a)
4 = Connecting
5 = 1+4 = Connected or Connecting
6 = 2+4 = 2 = Disconnected or Connecting
7 = 3+4 = Disconnected or Connected or Connecting
8 = Disconnected

Synopsis[edit]

/scid -rats<type> [Connection ID] [command]

Switches[edit]

-r - Resets the connection back to what it original was.
-s - Prints the current connection ID or the new connection ID.
-a - Perform on all connections.
-t<type> - Perform on all the connections of a specific type, can only be used with -a.

Parameters[edit]

<ID> - The connection ID.
<type> - The connection type, used with the -t switch.

Example[edit]

A simple example of using /scid to send a command to all connected connections.

/*
** Global amsg - performs an amsg on all the
** the actives connections you are on.
**
** /gamsg <message>
*/
alias gamsg {
  if (!$1) {
    echo -gtcse info * /gamsg: insufficient parameters
    halt
  }
  ; all active connections
  ; if you don't use $unsafe, $1- is evaluated twice, watch out!
  scid -at1 amsg $unsafe($1-)
}

Print all the channels you are on from every connection you have:

alias listChans {
  var %x = 1
  while ($scid(%x)) {
    ; switch connection
    scid %x
 
    ; iterate over the channels
    var %c = 1, %chans
    while ($chan(%c)) {
      var %chans = $addtok(%chans, $chr(32) $v1, 44)
      inc %c
    }
 
    ; print channels
    ; again, safer to use $unsafe
    scon -r echo -s $unsafe(Network: $network Channels: %chans)
 
    ; next connection
    inc %x
  }
}

Compatibility[edit]

Added: mIRC v6.0
Added on: 03 Feb 2002
Note: Unless otherwise stated, this was the date of original functionality.
Further enhancements may have been made in later versions.