Revision as of 17:02, 12 December 2019

By now, you should have a pretty good idea of what variables are and how to use them. Now, all you need to be able to do is operate on them. That's exactly what mIRC Operators lets you do. Operators are special symbols or keywords that perform specific operations on two or three operands in mIRC.

Operators

mIRC provides the following types of operators:

• Arithmetic Operators
• Math Comparison Operators
• String Comparison Operators
• Lexicographical String Comparison Operators
• Logical Operators
• Channel-related Operators
• List-related Operators

Arithmetic Operators

mIRC supports the following arithmetic operators:

They can be used in conjunction with the /var or /set commands as well as using the $calc Identifier. One special feature of the $calc identifier over the /var and /set commands is that it supports combination of operators as well as parenthesis to be able to change the order of operations.

alias example {
  var %x = 5
  ;5 * 5 = 25
  %x = %x * 5
  echo -a %x
 
  ;remainder of 25 / 9 = 7
  var %y = %x % 9
  echo -a %y
 
  ;25 + 7 - 2 = 30
  %x = $calc(%x + %y - 2)
  echo -a %x
}

Math Comparison Operators

Math Comparison operators allow you to compare two values:

Example:

alias example2 {
  ;true (3 a multiple of 9)
  if (3 // 9) echo yes!
  ;false
  if (4 < 4) echo no
  ;00001010 = 10
  ;00000100 = 4
  ;00000000 = 0
  ;true, we used the '!' to negate the operator
  if (10 !& 4) echo yes
}

String Comparison Operators

mIRC provides a set of operators that can be used to compare two strings. The two iswm and iswmcs operators support two wildcard characters as well, the question mark (?) substitutes for any one character and the asterisk character ("*") substitutes for any zero or more characters.

Example:

alias example3 {
  var %x = Hello!
  if (?ell?? iswm %x) echo true
  ;false, because of '!'
  if (%x isalpha) echo no
  %x = 5
  if (%x isnum 1-10) echo true
  if (%x isnum)  echo true
}

Lexicographical String Comparison Operators

A lexicographical comparison is a comparison generally used to sort words alphabetically in dictionaries and indexes. If both strings are equal but one is shorter than the other, the shorter string is lexicographically less than the longer one.

Logical Operators

In an if statement, you are allowed to have more than one condition. Each condition has to be connected to the other using a logical operator. There are two logical operators: || meaning OR and && meaning AND.

Example:

if ((%x < 0) || (%x >  10)) {

In the if statement above, %x has to be less than 0 OR greater than 10 to make the if statement be true.

if ((%input isupper) && ($len(%input) < 10)) {

The if statement above will only be true if %a contains only upper case letters and its total length is less than 10.

Short-circuit evaluation

mIRC will only evaluate as much of the condition has it needs. Consider the AND example from above, if %input doesn't contain only upper case letters, the second condition will never even evaluate. This is important to keep in mind when using custom identifiers inside an if statement.

Channel-related Operators

mIRC also provides a set of commands to involve IRC channels:

Example:

alias example4 {
  ;am I on #mIRC
  if (#mIRC ischan) echo yes
  ;is that ban on #mSL's internal ban list?
  if (*!*@example.com isban #offTopic) echo yes
  ;am I an OP on #mIRC?
  if ($me isop #mIRC) echo yes
}

List-related Operators

mIRC has 5 additional operators to check mIRC internal lists:

Example:

Alias example5 {
  ;is the host in the auto-op list
  if (dave101!*@* isaop) echo yes
 
  ;assume we have ignore all ctcps: /ignore -tw *!*@*
  ;check if *!*@* in the ignore list for CTCPs:
  if (*!*@* isignore ctcp) echo yes
}