Revision as of 02:30, 26 June 2014

Template:mIRC Guide Dialog Components are individual dialog elements that can be added onto the main dialog window. Below is a list of all the natively provided dialog components in mIRC.

Components

Button

The button control is a user interface control that responds to click events.

Synopsis

button "<text>", <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 50
  option dbu
  button "Example 1", 1, 4 10 40 12
  button "Example 2", 2, 50 10 40 12
  button "Example A", 3, 4 30 40 12
  button "Example B", 4, 50 30 40 12, ok
}
; event
on *:dialog:example:sclick:1-4:{
  echo -a $did($dname, $did).text is clicked.
}

Check Box

The checkbox control is a user interface element that permits the user to select or deselect an option. The checkbox control is a combination of a check box and a label. The mIRC check control has three states: Checked, Unchecked, and Indeterminate.

Synopsis

check "<text>", <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 50
  option dbu
  check "Example 1", 1, 4 10 40 12, 3state
  check "Example 2", 2, 50 10 40 12
  check "Example 3", 3, 4 30 40 12
  button "Done", 4, 50 30 40 12, ok
}
; events
on *:dialog:example:init:0:{ 
  did -cu $dname 1
  did -c $dname 2
}
on *:dialog:example:sclick:1-3:{
  echo -a $did($dname, $did).text is clicked. $&
    State: $dstate $+ .
}
alias -l dstate {
  var %s UnChecked Checked Indeterminate
  return $gettok(%s, $calc($did($dname, $did).state + 1), 32)
}

Toggle Button

A toggle button is a specialized button control which has the ability to be selected in the form of a pressed button. Like a checkbox control it has a checked and an unchecked state. A toggle button cannot have a third state.

Synopsis

check "<text>", <id>, <x> <y> <width> <height>, push[ <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 90 60
  option dbu
  text "Type:", 1, 4 5 60 10
  check "Grayscale", 2, 20 4 30 10, push
  text "R:", 3, 5 20 6 10
  edit "255", 4, 12 19 15 10
  text "Black:", 5, 30 20 15 10
  edit "100", 6, 45 19 15 10
  text "G:", 7, 5 32 6 10
  edit "255", 8, 12 31 15 10
  text "B:", 9, 5 44 6 10
  edit "255", 10, 12 43 15 10
  button "Done", 11, 40 40 40 12, ok
}
on *:dialog:example:init:0:{
  did -b example 5,6
}
on *:dialog:example:sclick:2:{
  did $iif(!$did(2).state, -b, -e) example 5,6
  did $iif($did(2).state, -b, -e) example 3,4,7-10
}

Label

A label is simply a GUI component with text designed for displaying information with no user input. By default, the text will wrap to the next line if needed.

Synopsis

text "<text>", <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 70
  option dbu
  text "This label does not wrap.", 1, 4 10 40 15, nowrap
  text "This is a simple label.", 2, 4 30 40 15
  text "I am right-aligned.", 3, 4 50 40 15, right
  button "Done", 4, 50 30 40 12, ok
}

Group

This is a static control with a group box frame and an optional title that shows up at the top of the frame.

Synopsis

box "<title>", <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

This control has no events.

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 90 120
  option dbu
  box "A Settings", 1, 4 4 80 40
  box "B Settings", 2, 4 50 80 40
  button "Done", 4, 40 100 40 12, ok
}

Image

An image control is a simple container that holds images and icons.

Synopsis

icon <id>, <x> <y> <width> <height>[, <filename>[, <index>]], <style>

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 110
  option dbu
 
  icon 1, 10 10 80 80, "C:\Users\Public\Pictures\Sample Pictures\Penguins.jpg", actual
 
  button "Done", 7, 10 95 40 12, ok
}

Text

The edit control can behave as a normal text box as well as a rich text control.

Synopsis

edit "<text>", <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 110
  option dbu
 
  edit "Lef", 1, 10 10 80 20,
  edit "Center", 2, 10 40 80 20, center
  edit "Right", 3, 10 70 80 20, right
 
  button "Done", 7, 10 95 40 12, ok
}

Scroll

A scrollbar is a simple dialog component that can be used to scroll something. A scrollbar operates within a given range.

Synopsis

scroll "<text>", <id>, <x> <y> <width> <height>, <style>

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 90 65
  option dbu
 
  text "0%", 1, 30 20 20 20
  scroll , 2, 60 5 5 40, range 0 100
 
  button "Done", 13, 25 50 40 12, ok
}
on *:dialog:example:scroll:2:{
  did -ra example 1 $did(example, 2).sel $+ %
}

List

The list control provides a way to display a list of items.

Synopsis

list <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 110
  option dbu
 
  list 1, 10 10 80 20, multsel
  list 2, 10 40 80 20, radio
  list 3, 10 70 80 20, check
 
  button "Done", 7, 10 95 40 12, ok
}
on 1:dialog:example:init:*: {
  did -a example 1 Item A
  did -a example 1 Item B
  did -a example 1 Item C
  did -a example 2 Item A
  did -a example 2 Item B
  did -a example 2 Item C
  did -a example 3 Item A
  did -a example 3 Item B
  did -a example 3 Item C
}

Combo

The combo control provides a way to choose an item from a selection of items in either a list, or from a drop-down fashion selection box.

Synopsis

combo <id>, <x> <y> <width> <height>[, <style>]

Styles

Events

Example

; init alias
alias example {
  dialog -m example example
}
; dialog structure
dialog Example {
  title "ZigWap - Example"
  size -1 -1 100 110
  option dbu
 
  combo 1, 10 10 80 50, drop
  combo 2, 10 50 80 50
 
  button "Done", 7, 10 95 40 12, ok
}
on 1:dialog:example:init:*: {
  did -a example 1 Item A
  did -a example 1 Item B
  did -a example 1 Item C
  did -a example 2 Item A
  did -a example 2 Item B
  did -a example 2 Item C
}